# $Id$
# Maintainer: Ronald van Haren
# Contributor: jlvsimoes
# Contributor: damir <damir@archlinux.org>
# Contributor: Valentine Sinitsyn <e_val@inbox.ru>

pkgname=kdemod3-k3b
_pkgname=k3b
pkgver=1.0.5
pkgrel=1
depends=('cdrdao' 'cdrkit' 'cdparanoia' 'kdelibs3' 'libsamplerate' 'lame' 'libidn' 'libmad'
	 'normalize' 'sox' 'hal>=0.5.8.1-6' 'ffmpeg>=0.5' 'musicbrainz' 'libart-lgpl'
	 'taglib>=1.4' 'libmpcdec>=1.2.5' 'libdvdread' 'dbus-qt3' 'flac>=1.2.0' 'libvorbis')
optdepends=('dvd+rw-tools: for DVD-Burner support')
provides=('k3b')
conflicts=('k3b')
pkgdesc="Feature-rich and easy to handle CD burning application (KDE3 version)"
arch=("i686" "x86_64")
license=('GPL')
source=(http://downloads.sourceforge.net/sourceforge/k3b/${_pkgname}-${pkgver}.tar.bz2
	http://www.mattparnell.com/zen/k3b/transcodeBugFix.patch)
md5sums=('e3b37d0d009af3dd149215d6ae0d54f3'
         '9f2f2d6278e4d63f94eed9c1a9349dbe')
url="http://k3b.sourceforge.net/"


build() {
  . /etc/profile.d/qt3.sh
  . /etc/profile.d/kde3.sh
  cd ${srcdir}/${_pkgname}-${pkgver}

  # Fix transcode/dvd ripping error
  patch -Np0 -i ${srcdir}/transcodeBugFix.patch || return 1

  ./configure --prefix=/opt/kde --enable-mt --disable-debug \
  		--enable-debug=no --with-k3bsetup=no \
		--without-cdrecord-suid-root \
		--enable-ffmpeg-all-codecs --without-arts
  make || return 1
  make DESTDIR=${pkgdir} install || return 1
}